justfile

verse_repo := env_var_or_default("VERSE_REPO", "../verse")

build:

	docker build --build-context verse={{verse_repo}} -t riddim .

build-release:

	#!/bin/bash

	DIR=$(mktemp -d)

	hg archive "$DIR"

	docker build --build-context verse={{verse_repo}} -t mwild1/riddim "$DIR"

	rm -rf -- "$DIR"

release: build-release

	docker push mwild1/riddim:latest

run:

	docker run --rm --env-file=CONFIG.env -v "$PWD/config.lua:/etc/riddim/config.lua" riddim

# Bring up a local Prosody+riddim and run the end-to-end test

test:

	cd test && docker compose up --build -d prosody riddim && docker compose run --build --rm tester

# Test recovery from a silent remote-MUC restart (XEP-0410, muc_ping plugin)

muc-test:

	#!/bin/bash

	set -ex

	cd test

	docker compose up --build -d prosody remotemuc riddim

	docker compose run --build --rm muc-tester 60

	# Kill the remote MUC server without letting it notify anyone, then bring

	# up a fresh instance that has no saved MUC state (and so no occupants)

	docker compose kill remotemuc

	docker compose up -d --force-recreate remotemuc

	docker compose run --rm muc-tester 120